Základy JSON v Delphi

{
  "name": "Henri Gourvest", /* this is a comment */
  "vip": true,
  "telephones": ["000000000", "111111111111"],
  "age": 33,
  "size": 1.83,
  "adresses": [
    {
      "adress": "blabla",
      "city": "Metz",
      "pc": 57000
    },
    {
      "adress": "blabla",
      "city": "Nantes",
      "pc": 44000
    }
  ]
}

var
  js:TlkJSONobject;
  i:Integer;
begin
  // vytvoreni objektu
  //js := TlkJSONobject.Create; // jednoduche vytvoreni
  js:=TlkJSON.ParseText('{}') as TlkJSONobject; // vytvoreni parsovanim

  // kontrola
  if js=nil then
    Exit;

  try
    // pridavani polozek, nazev je string, hodnota může vzít různé typy
    js.Add('jmeno','hodnota-1');
    // pridat dalsi polozku se stejnym jmenem u lkJSON jde
    // hodnotu uz ale vzit asi nejde
    js.Add('jmeno','hodnota-2');

    // pridani polozky, ktera jako hodnotu obsahuje dalsi objekt {}
    js.Add('objekt',TlkJSONobject.Create);

    // pridani polozky do pod-objektu
    (js.Field['objekt'] as TlkJSONobject).Add('jmeno-objekt','hodnota-3');

    js.Add('pole',TlkJSONlist.Create); // vytvoreni pole []
    (js.Field['pole'] as TlkJSONlist).Add(20); // pridani polozky do pole

    // cteni polozek
    ShowMessage('Podle indexu: '+js.getString(0)); // podle indexu
          // pomoci .Field a indexu
    ShowMessage('Pomoci field: '+(js.FieldByIndex[1] as TlkJSONstring).Value); 
    ShowMessage('Podle nazvu: '+js.getString('jmeno')); // pomoci nazvu

    // cteni z podobjektu
    ShowMessage('Podobjekt: '+
           (js.Field['objekt'] as TlkJSONobject).getString('jmeno-objekt'));

    // prochazeni struktury JSON
    // asi lze vyuzit "for … in … do" jako u SuperObject, ale to jsem netestoval 
    for i := 0 to js.Count - 1 do
      case js.FieldByIndex[i].SelfType of
        jsString: ShowMessage('Prochazeni: '
             +VarToStr((js.FieldByIndex[i] as TlkJSONstring).Value));
        // …
      end;    

    // generovani JSON datove struktury pro prenos
    //Memo1.Lines.Text:=TlkJSON.GenerateText(js); // jen text
    i:=0;
    Memo1.Lines.Text:=GenerateReadableText(js,i); // strukturovany text
  finally
    //js.Free;
    FreeAndNil(js);
  end;
end;

var
  json: ISuperObject;

  // promenne pro prochazeni
  item1: ISuperObject;
  item2: TSuperAvlEntry;
  item3: TSuperObjectIter;
begin
  // vytvoreni
  json := SO(); // v zavorce lze parsovat JSON

  if json=nil then
    Exit; // jen pro jistotu, ze objekt byl vytvoren

  // jeste pro jistotu, ze to je objekt {}
  // pri parsovani prazdneho textu neni a nefungovalo by to spravně
  // jeste to muze byt pripadne pole []
  if not json.IsType(stObject) then
    begin
      json:=nil;
      Exit;
    end;

  try
    // pridavani a cteni polozek
    // S[] - string
    // I[] - integer
    // B[] - boolean …
    // specialni vyznam v nazvu maji tecka, (), [], mozna neco dalsiho
    // json.ForcePath('nazev-prvku'); //zaruci existenci prvku
    json.S['jmeno-str']:='hodnota-1';
    json.I['jmeno-int']:=11;

    // prace se strukturou, slozitejsi metoda
    json.O['objekt']:=SO; // vytvoreni objektu, stejne jako ForcePath
    json.O['objekt'].S['jmeno-sub']:='hodnota-2'; // pridani polozky

    // zkraceny zapis pro vytvareni i cteni
    // tecka znaci praci s hodnotou, ktera je v podobjektu 
    // hranate zavorky slouzi k praci s hodnotami pole
    // kulate zavorky jsou pro volani metod - zde je mozne se vyuzit hodnot v JSON
    // knihovna ohlida a vytvori potrebnou strukturu
    json.S['objekt-2.jmeno-sub-1']:='hodnota-3'; // vytvori objekt i polozku
    json.S['pole[]']:='polozka pole'; // vytvoreni a pridani polozky do pole
    json.S['pole[2]']:='polozka dalsi'; // vytvoreni a pridani polozky na pozici

    // cteni polozky podle indexu
    // (nevim o jinym jednodussim reseni)
    ShowMessage(json.AsObject.GetValues.AsArray[3].AsString);

    // prochazeni vsech polozek - moznost 1
    // POZN.: Array ma polozku Length, Object ma Count    
    for item1 in json do
      case item1.DataType of
        // superobject dovoluje cist integer jako string
        stString, stInt: ShowMessage('Prochazeni 1: '+item1.AsString);
        //…
      end;

    // prochazeni - moznost 2
    for item2 in json.AsObject do
    begin
      case item2.Value.DataType of
        stString, stInt: ShowMessage('Prochazeni 2: '+item2.Name+' : '
           +item2.Value.AsString);
        // …
      end;
    end;

    // prochazeni - moznost 3
    if ObjectFindFirst(json, item3) then
    repeat
      case item3.val.DataType of
        stString, stInt: ShowMessage('Prochazeni 3: '+item3.key+' : '+
           item3.val.AsString);
        // …
      end;
    until not ObjectFindNext(item3);
    ObjectFindClose(item3);

    // v zavorce - strukturovany / nestrukturovany vystup
    Memo1.Lines.Text:=json.AsJSon(True);
  finally
    // uvolneni
    json:=nil;
  end;
end;